《社交网络》MarkZackburg被女朋友甩后的ELO等级分制度

时间：2022-07-28 17:03:38 来源：网络整理

《社交网络》中的马克·扎克伯格在被女友甩后，在室友的启发下，充分发挥了技术宅男自娱自乐的恶搞天赋足球世界排名计算方法，创建了一个名为Facemash的网站进行长相分析的女生。排名打分足球世界排名计算方法，结果网站流量太大，直接瘫痪了学校网络。 Facemask受欢迎的关键在于Zackburg的朋友Eduardo在橱窗上写的排名公式。我在看电影的时候对这个排名公式很感兴趣。上网看了下，发现这个公式就是大名鼎鼎的ELO评分系统。 ELO的应用非常广泛。大多数棋类游戏和流行的Moba游戏，例如11平台的DOTA天梯系统，都使用ELO等级分。

未来竞技游戏的排名可以通过ELO排名，更真实的体现玩家的实力。闲来无事做了个flash面罩，很有意思。

ELO的实现代码

package
{
    
    /**
     * Elo排名算法
     * @author ShuchangLiu
     */
    public class EloRating
    {
        public static const ELO_RESULT_WIN:int = 1;
        public static const ELO_RESULT_LOSS:int = -1;
        public static const ELO_RESULT_TIE:int = 0;
        
        public static const ELO_RATING_DEFAULT:int = 1500;
        
        protected var rating1:int;
        protected var rating2:int;
        protected var score1:Number;
        protected var score2:Number;

        
        public function EloRating(rating1:int = ELO_RATING_DEFAULT, rating2:int = ELO_RATING_DEFAULT):void
        {
            this.rating1 = rating1;
            this.rating2 = rating2;
        }
        
        /**
         * @param result ELO_RESULT_WIN or ELO_RESULT_LOSS or ELO_RESULT_TIE
         */        
        public function setResult(result:int):void {
            var cscore1:Number = computeScore(this.rating2, this.rating1);
            var cscore2:Number = computeScore(this.rating1, this.rating2);
            
            if (result == ELO_RESULT_WIN) {
                this.rating1 = this.rating1 + (computeK(this.rating1) * (1 - cscore1));
                this.rating2 = this.rating2 + (computeK(this.rating2) * (0 - cscore2));
            }else if(result == ELO_RESULT_LOSS) {
                this.rating1 = this.rating1 + (computeK(this.rating1) * (0 - cscore1));
                this.rating2 = this.rating2 + (computeK(this.rating2) * (1 - cscore2));

            }else{
                // Assume tie
                this.rating1 = this.rating1 + (computeK(this.rating1) * (0.5 - cscore1));
                this.rating2 = this.rating2 + (computeK(this.rating2) * (0.5 - cscore2));
            }
        }
        
        protected function computeScore($rating1:int, $rating2:int):Number {
            return (1 / (1 + Math.pow(10, ($rating1 - $rating2) / 400)));
        }
        
        protected function computeK(rating:int):int {
            if(rating>=2400){
                return 16;
            }else if(rating >= 2100){
                return 24;
            }else{
                return 36;
            }
        }

        
        /** A的获胜期望*/
        public function getScore1():Number {
            this.score1 = computeScore(this.rating2, this.rating1);
            return this.score1;
        }
        
        /** B的获胜期望*/
        public function getScore2():Number {
            this.score2 = computeScore(this.rating1, this.rating2);
            return this.score2;
        }
        
        /** A的排名等级*/
        public function getRating1():int {
            return this.rating1;
        }
        
        /** B的排名等级*/
        public function getRating2():int {

            return this.rating2;
        }
        
        
        
    }
}